# Description: adds the /at command, which runs a command once at the specified time

procs command_at

proc command_at {window line} {
    global prefs info
    set line [split [string trimleft $line]]
    if {$line == ""} {
        set found 0
        foreach x [after info] {
            if {[string match *::doat [lindex [after info $x] 0 0]]} {
                set line [lindex [after info $x] 0]
                Echo $window "at [clock format [lindex $line 1] -format "(%m/%d/%y %H:%M:%S)"] [lindex $line 2]"
                set found 1
            }
        }
        if {!$found} {Echo $window {[ info ] There are no at commands pending}}
        return
    }
    if {[lindex $line 0] == "stop" || [lindex $line 0] == "cancel"} {
        set line [lrange $line 1 end]
        set cancel 1
    }
    set time [gettime line]
    if {$line == "" || [llength $line] == 1} {
        Echo $window {[ info ] Usage: /at [[cancel|stop] <time> <command>]}
        return
    }
    if {$time == ""} {
        Echo $window "\[ error \] Invalid time"
        return
    }
    set till [expr $time - [clock seconds]]
    if {$till < 0 && $till > -86400} {
        incr till 86400
        incr time 86400
    }
    if {[info exists cancel]} {
        foreach x [after info] {
            set y [lindex [after info $x] 0]
            if {[string match *::doat [lindex $y 0]] && $time == [lindex $y 1] && [string match [globescape $line]* [lindex $y 2]]} {
                after cancel $x
                Echo $window "-at [clock format $time -format "(%m/%d/%y %H:%M:%S)"] [lindex $y 2]"
            }
        }
        return
    }
    after [expr $till*1000] [list [namespace current]::doat $time $line]
    Echo $window "+at [clock format $time -format "(%m/%d/%y %H:%M:%S)"] [join $line]"
}

proc gettime {var} {
    upvar $var line
    set len [expr {[llength $line] - 1}]
    for {set num 0} {$num <= $len} {incr num} {
        if {![catch {clock scan [lrange $line 0 end-$num]} time]} {
            set line [lrange $line end-[expr {$num - 1}] end]
            return $time
        }
    }
    return {}
}

proc doat {time cmd} {
    if {[catch {eval $cmd} out]} {Echo .0 "\[ error \] Error in at command: $out"}
}

proc help {window line} {
    switch -exact -- $line {
        default {
            Echo $window {[ help ] Commands added by this script: /at}
            Echo $window {[ help ] Usage: /at [[cancel|stop] <time> <command>]}
            Echo $window {[ help ] Executes <command> once at the time specified by <time>}
            Echo $window {[ help ] <time> may have any format acceptable to the "clock scan" command, see man n clock}
        }
    }
}

proc unload {} {
    foreach x [after info] {
        if {[string match *::doat [lindex [lindex [after info $x] 0] 0]]} {after cancel $x}
    }
}